macro
lognormalpaper cycles

#Copyright © 20 December 2000 Mathews and Malnar All rights reserved
#Rev. 1.0 for Minitab V13.3 (Bek)
#Rev. 1.1 1/20/02 PGM: Changed calling structure for number of cycles.

#This macro is used to construct two or three cycle normal probability
#plotting paper to be used for hand plotting data. The user must specify the
#number of cycles (2 or 3) for the data scale.

#Mathews, Malnar & Bailey
#217 Third Street, Fairport Harbor, OH 44077
#(440)350-0911
#pmathews@apk.net

#MM&B offers training in this and other Quality services.
#Call or email for details.

#This macro should be copied into the Minitab source macros directory for
#immediate use, otherwise a change directory (cd) command will be needed.

#Example call:
#	mtb> %lognormalpaper 2


#Copy the following line, minus the leading #, to the command line:
#%lognormalpaper 3


mcolumn p xlabel ylabel z ygrad x y P2 Z2 yref 
mconstant cycles

set p
 0.001 0.005 0.010 0.050 
 0.100:0.900/0.100
 0.950 0.990 0.995 0.999
 end

TSet xlabel
   1(  "0.1" "0.5" "1" "5" "10" "20" "30" "40" "50" "60" "70" "80" "90" "95" "99" "99.5" "99.9" )1
   End.

invcdf p z

If cycles=2
  set yref
    1 10 100
    end
  Text yref ylabel
  set ygrad
     1:10/1
     10:100/10
     end
Elseif cycles=3
  set yref
    1 10 100 1000
    end
  Text yref ylabel
  set ygrad
     1:10/1
     10:100/10
     100:1000/100
     end
Else
   Note Error: The number of cycles must be 2 or 3.
   return
endif

set P2
 0.002:0.004/0.001
 0.020:0.040/0.010
 0.060:0.090/0.010
 0.150:0.850/0.100
 0.910:0.940/0.010
 0.960:0.990/0.010
 0.996:0.998/0.001
 end
 
invcdf P2 Z2

set x
 0
 end

set y
 1
 end

Plot y*x;
   Symbol;
     Type 0;
   LogScale 2;
   Footnote "Copyright ©2000 Mathews & Malnar";
     TSize 0.5;
     Right;
   Data 0.1 0.95 0.1 0.95;
   Minimum 2 9;
   ScFrame;
   ScAnnotation;
   Axis 1;
     Label "Normal Probability (%)";
     TSize 0.9;
   Axis 2;
     Label " ";
   Tick 1 z;
     Labels xlabel;
     TSize 0.8;
   Tick 2 yref;
     Length 0.0 0.0;
     Labels ylabel;
     TColor 15;
     TSize 0.8;
   Reference 1 z;
   Reference 2 ygrad;
   Reference 1 Z2.

endmacro